ひとつ前へ　WWWルートへ　mad@mail.wind.ne.jp

SPICEによる設計（正電源から負電源を作る）

（C)数理設計研究所　玉置晴朗　2002/01/27 12:00-22:30

目的：

　＋５〜１２Vの単一電源システムにおいてOPアンプで両極性の信号を扱うためにわずかな電流を供給する負電源があればバイアス回路が楽になる。
　そこで７５５５を発振器に使うラダー型逆電圧生成回路の負荷特性を調査する。初心者のため情報収集からSPICEによる検討まで、流れを追ってここに掲載する。

設計仕様：

  • ラダー型の整流回路で逆電圧を作る
  • 交流源は５５５またはCMOS版の７５５５
  • 1S1558がないので、同じ感じの1SS82
  • ＋５Vから−５Ｖ（１ｍＡ）が目標

調査：

http://www.google.co.jp/　でキーワードを（7555 pdf timer）として検索すると、

[PDF] ICM7555, ICM7556
ファイルタイプ: PDF/Adobe Acrobat - HTMLバージョン
Page 1. 1 TM July 2001 ICM7555, ICM7556 General ... Americas
Inc. 2001 Page 2. 2 Absolute Maximum Ratings ...
www.intersil.com/data/FN/FN2/FN2867/FN2867.pdf - 関連ページ
が４行目にでてきたので、これをicm7555.pdfとして保存。

ダイオードSPICEモデル（１ＳＳ８２）は
http://www.madlabo.com/mad/edat/spice/diode.lib
* High-V Switching
.model d1ss82 D(IS=1.10E-8 N=1.98 RS=2.10
+ CJO=1.33pf VJ=0.149 M=0.1023 TT=50ns BV=300 IBV=100E-15)
★バグあるよ
  • ７５５５の出力設定にバグ判明。
  • 出力抵抗１５０Ω一定とみなして、７５５５の標準値の3倍ほど低性能だと思えばこのままの結果でOK
  • 問題がどこにあるか捜すのもおもしろいだろう
目次

考察

ＩＣＭ７５５５データシート

　７５５５はＣ−ＭＯＳの汎用タイマＩＣである。一般的なＳＰＩＣＥモデルがあったとしても、ここで検討するのＩＣの動作特性ではなく逆電圧を生成しどんな負荷特性になるかを調査するので７５５５はDuty50%、1kHz-100kHz範囲で発振するとしてしまう。問題となるのは出力特性なのでデータシートを見る。
　icm7555.pdfに以下のドキュメントに示す指示番号（ＺＡ２とか）が参考のために書き込まれている。
  • ＺＡ１（Page3)　最悪値評価　Vdd@5V
    • L出力時：流れ込み（ISINK)が3.2mA時に電圧0.5V
      RL(max)=0.5/3.2(kohm)=156ohm
    • H出力時：供給電流（ISOURCE)が0.8mA時に3.8V
      RH(max)=(5-3.8)/0.8(kohm)=1500ohm
  • ＺＡ２(Page4)　電源ノイズ
    • バイポーラト製造の555では380mAのスパイク
    • C-MOS版のICM７５５５ではスパイクは無い
  • ZA3(Page5)　回路と発振周波数
    • Duty50%の自走発振器回路と発振周波数
  • ZA4(Page6)　消費電流(@5V)
    • -20℃のときに最大になり100uA
  • ZA5(Page6)　標準的なH出力抵抗
    • 20℃における出力電流0.05Vの電圧降下で2mA
      RH(typ)=0.05/2(kohm)=25ohm
  • ZA6(Page6)　標準的なL出力抵抗
    • 20℃、0.5Vの電圧降下で10mAの流れ込み電流
      RL(typ)=0.5/10(kohm)=50ohm
  • ZA6(Page7)　発振周波数と発振抵抗
    • 1kHz〜100kHzにを決めると100kohmぐらい
    • f=1/(1.4 R C)　よりR=100kohm f=10kHzで0.7nF、0.001uFだとおよそ7kHzとなる。

ICM7555出力部のSPICEモデル


　最悪値設計をおこなうとH出力時に１．５ｋオーム。しかし、あまりにも標準値の２５オームより大きいので１ｋオーム、吸い込み側では最悪値の１５６オームとする。
　
　パルス周期は７ｋHz、DUTY５０％として計算。

ラダーのCは1uF、7kHzのときのインピーダンスは
Zc=1/(2*3.14*7k*1u)=22.73ohm
なので出力抵抗よりかなり小さい、0.1uF(227ohm@7kHz)なので使えるかもしれない。

電流目標は1mA

参考：PSPICEのコマンド

http://astro7.yy.kagu.sut.ac.jp/~wwwsm/TA/3OB/Buhin.html
↑のURLが失われたときのためのバックアップ

ラダー型整流回路

シミュレーション

発振出力の設定

７ｋHz、0-5Vの矩形波を出力する
ICM7555 to Ladder Reverse Power GENERATOR
.OPT ACCT NOMOD NOPAGE RELTOL=.001
.lib diode.lib
.TRAN 1nS 5m

;信号源
vsrc n1 0 pulse(0v,5v,0,0.1u,0.1u,70u,140u)

;7555の出力モデル
d1 n1 n2 d1ss82
r1 n1 out7555 156
r2 n2 out7555 1k

;負荷抵抗
rl out7555 0 10k
.probe
.end

出力結果：７ｋHzの矩形信号が出ている、あたりまえだけど・・・

ラダー型整流回路と負荷抵抗

ICM7555 to Ladder Reverse Power GENERATOR
.OPT ACCT NOMOD NOPAGE RELTOL=.001
.lib diode.lib
.TRAN 1nS 12m

;信号源
vsrc n1 0 pulse(0v,5v,0,0.1u,0.1u,70u,140u)

;7555の出力モデル
d1 n1 n2 d1ss82
r1 n1 out7555 156
r2 n2 out7555 1k

;倍電圧整流のラダー回路
c1 out7555 n10 1u
d2 n10 0 d1ss82
d3 n11 n10 d1ss82
c2 n11 0 1u
r3 n11 n12 100
c3 n12 0 1u


;負荷抵抗
.param rv = 10k
.step param rv list 2k 5k 10k
rl n12 0 { rv }
.probe
.end		 　負荷抵抗を２，５，１０ｋオームにした3種類のシミュレーションを続けて実行する。
.param rv = 10k　　;ｒｖ変数を使うため始めに宣言
.step param rv list 2k 5k 10k 　　;スィープの指定
rl n12 0 { rv }　　　　;変数は{ }の中に指定

シミュレータ
PSPICE　Ver5.2　DOS版

図面インターフェースがはやりだが、私はこれを使う。図面の必要が無いのにわざわざ図面を書く手間がもったいない。

負荷抵抗（RL=2ｋ）


負荷抵抗（RL=2ｋ）　１０ミリ秒後に−２．７Vに達している

負荷抵抗（RL=５ｋ）


負荷抵抗（RL=５ｋ）　１０ミリ秒後に−３．３Vに達している

負荷抵抗（RL=１０ｋ）


負荷抵抗（RL=１０ｋ）　１０ミリ秒後に−３．５８Vに達している

データ整理

負荷抵抗（ｋohm） １０ミリ秒後の電圧(V) 電流(mA)
２ −２．７ １．３５
５ −３．３ ０．６６
１０ −３．５８ ０．３５８
シミュレーション結果を表にして左下のグラフにする
　左表より、最悪値でも出力電流1mAのときに、負荷抵抗3kohm、出力電圧3Vが期待できる。

リップル評価

フィルタの前

負荷抵抗5kohmのときのフィルタ前(n11)リップル。　42.7mVP-Pが観察され、けっこう大きい。
フィルタの後

負荷抵抗5kohmのときのリップル。7.66mVP-Pが観察され、まずまず。

結論

　OPアンプの電源として1mAを利用するとして＋５Vから−３．３Vは問題なく作成できる。
　C=1u,　７ｋHzで特に問題は無い。周波数を高くすると電源からの回り込みも増える可能性が高いので７ｋHzは妥当だろう。
　リップルも１段のCRフィルタで問題無い。		 　
　 　

..end