SPICE PSPICE MODEL LIBRARY

ひとつ前へ　 WWWルートへ　 mad@mail.wind.ne.jp

Spice Model

2003/10/05　-　2009/1/10　Hal.T

Index

Diode
Bipola Transistor
FET
マクロモデル
パッケージ

信頼度と言えばいいのか、適用回路にもよりますが

データシートからいいかげんに作ったもの
別文献に掲載していたもの
実際に試験して決めたもの
メーカー提供

が混在しています、可能な限りコメントを書いておきますね。
実験して違うならば、回路や結果を通報していただければ
（いずれ）モデルを作り直すこともあるかな。保障はしません。

掲示板システムを作ってみたここの掲示板ってところ
Homepage ってところに更新時の自動通報があります

Diode

パラメータ定義

IS nominal leakage current
RS for zener diodes: nominal small-signal impedance at specified operating current
IB for zener diodes: set to nominal leakage current
IBV for zener diodes: at specified operating current
IBV is adjusted to give the rated zener voltage

1N60 ゲルマニウム 2003/10/05 Hal.T

.model D1N60 D(IS=1.6E-15 N=0.3439 RS=72.1 CJO=1PF)
.model D1N60 D(IS=1.6E-15 N=0.3439 RS=72.1 CJO=1PF BV=10 IBV=100E-15)　;たぶん

実測値 2001/10/05

E(V) 0.3 0.4 0.5 0.6 0.7 0.8 0.9

I(mA) 1 2.1 3.3 4.7 6.2 7.6 9.4

1N752 Zener

.MODEL D1N752 D (IS=0.5UA RS=6 BV=5.20 IBV=0.5UA)

1N754 Zener

.MODEL D D (IS=0.05UA RS=3 BV=6.41 IBV=0.05UA)

1N759 Zener

.MODEL D1N759 D (IS=0.05UA RS=15 BV=11.37 IBV=0.05UA)

1N914

.MODEL D1N914 D (IS=100E-15 RS=16 CJO=2PF TT=12NS BV=100 IBV=100E-15)

1N916

.MODEL D1N916 D (IS=100E-15 RS=8 CJO=1PF TT=12NS BV=100 IBV=100E-15)

ショットキー　TTL内部の保護ダイオード

.model dsbd D(IS=1E-14 RS=264 CJO=0.06pf VJ=0.5 EG=0.69 TT=0.1ns)

電源用のショットキー　ＳＢＤ

.model dpsbd D(IS=2E-3 N=2 RS=0.01 CJO=1nf TT=10ns BV=40v IBV=100E-15)

1S2074 HItachi Si EP High speed switch CQ 1988/7

.model d1s2074 D(IS=1.443E-9 N=1.708 RS=1.466 CJO=1.92pf VJ=0.4996 M=0.0605 TT=3ns BV=120 IBV=100E-15)

1s2075 HItachi Si EP High speed switch

.model d1s2075 D(IS=1.387E-9 N=1.702 RS=1.53 CJO=1.92pf VJ=0.4996 M=0.0605 TT=5ns BV=75 IBV=100E-15)

1s2090 HItachi Si EP UHF TV AFC P-64

.model d1s2090 D(RS=2.36 CJO=9.96pf VJ=0.9140 M=0.4199 )

1s2267 HItachi Si EP UHF TV AFC P-65

.model d1s2267 D(RS=1.18 CJO=25.6pf VJ=2.6510 M=1.0961 )

1s2268 HItachi Si EP UHF TV AFC P-65

.model d1s2268 D(RS=1.00 CJO=25.6pf VJ=2.6510 M=1.0961 )

1ss16 Shotkey Barier

.model d1ss16 D(IS=2.18E-6 N=1.07 RS=2.1 CJO=1.13pf VJ=1.336 M=0.2244 TT=0.1ns BV=6v IBV=100E-15)

1ss81 High-V Switching

.model d1ss81 D(IS=1.10E-8 N=1.98 RS=2.10 CJO=1.33pf VJ=0.149 M=0.1023 TT=50ns BV=250 IBV=100E-15)

1ss82 High-V Switching

.model d1ss82 D(IS=1.10E-8 N=1.98 RS=2.10 CJO=1.33pf VJ=0.149 M=0.1023 TT=50ns BV=300 IBV=100E-15)

1ss86 Hitachi Si SBD UHF-TV tuner Mixer

.model d1ss86 D(IS=1.504e-6 N=1.0914 RS=17.64 CJO=1.04pf TT=.1ns BV=20 IBV=100E-15)

1ss88 Hitachi Si SBD CATV balanced Mixer

.model d1ss88 D(IS=6.47E-10 N=1.0594 RS=11.933 CJO=1.04pf VJ=0.294 M=0.1082 TT=.1ns BV=20 IBV=100E-15)

1ss106 Hitachi Si SBD General Detector & High speed SW

.model d1ss106 D(IS=2.35E-5 N=2.524 RS=48.12 CJO=1.36pf VJ=0.294 M=0.1635 TT=.1ns BV=40 IBV=100E-15)

1ss108 Hitachi Si SBD General Detector & High speed SW

.model d1ss108 D(IS=4.86E-5 N=2.105 RS=58.7 CJO=1.62pf VJ=2.267 M=0.2857 TT=.1ns BV=60 IBV=100E-15)

1SS110 Hitachi Si EP BAND Switching in UHF/VHF TUNER 1992/09/30 Hal.T

*MIN Vbr=35V @ 10uA,
*MAX Ir=0.1uA @ Vr=25v Vf=1.0V @ If=10m C=1.2pF @Vr=6V f=1MHz
*MAX rf=0.9ohm @If=2mA　動作抵抗
*Typ リードインダクタンス 3nH
*動作温度－２０～６０、保存温度－５５～１２５
*許容損失１５０ｍＷ、順電流最大値１５０ｍＡ、逆電圧最大値３５Ｖ
*TT を設定して４３０ＭＨｚ近傍で電流とＲＦ抵抗が一致するようにしている
.model d1SS110 D(IS=3e-11 N=1.645 RS=0.45 CJO=1.83pf VJ=0.2327 M=0.1599 TT=.02us BV=60 IBV=100E-15)

1SS174

.model d1SS174 D(IS=2.18E-6 N=1.07 RS=2.1CJO=1.13pf VJ=1.336 M=0.2244 TT=3ns BV=35v IBV=100E-15)
*SBD General Switchng for UHF-TV Mixer P112

1sv99 PIN diode

*50v 50ma (@100Mhz 1u=5k 10u=2k 100u=300 1m=50 10m=8 IF=ohm)
.model d1sv99 D(IS=5.67E-10 N=1.9050 RS=0.9725 CJO=0.525pf VJ=0.1396 M=0.07550 TT=1us BV=50v IBV=100E-15)

1SV134

*1v=500pF 4v=130pF 9v=30pF
.model d1sv134 D(CJO=9.17e-10 VJ=4.9775 M=3.3121 BV=70v IBV=100E-15)
* Hitachi AM tuner VC

DBF150　電源整流用の単相ブリッジ

.model DBF150 D(IS=7.2286E-15 N=0.98 RS=0.0123469 CJO=1000pf TT=30us BV=200 IBV=100E-15)
*SANYO 15A単相ブリッジ　50Hz試験　Hal.T 2007/04　2007/05/07
DBF150C.pdf　dbf150.asc

DZD2.0-24

SANYO_ZENER.pdf

ED7TV1

.model ded7tv1 D(IS=9.5E-15 N=15.3 RS=5.5 CJO=1.33pf VJ=0.149 M=0.1023 TT=500ns BV=7000 IBV=100E-15)
*High-V Switching Origin P136/TR 88 dioade manual

GMA02

.model GMA02 D(IS=1.10E-8 N=1.98 RS=2.10 CJO=3.00pf TT=75ns BV=250 IBV=100E-15)
*Si SW　過渡応答試験　2007/04 Hal.T
GMA02.pdf

hse11 Hitachi GaAs SBD BS-Converter(12GHz) Mixer

* ＢＳコンバーター用１ｓｔミキサ用　ＧａＡｓショットキーバリア Vr=4.0V If=50mA If(peak)=150mA
.model dhse11 D(IS=3.43E-13 N=1.166 RS=1.267 CJO=0.29pf VJ=0.292 M=0.1293 TT=.01ns BV=5 IBV=100E-15)

HVU316 Hitachi BS tuner VC

* ＢＳコンバーター用バリキャップ Vr,C = (1,6.2p),(5,2.45p),(10,1.25p)
.model dhvu316 D(CJO=8.96pf VJ=3.449 M=1.4477 BV=35 IBV=100E-15)

FC51 Fujitsu tuninge VC FC51A FC51H

* Vr,C = (1,180p),(4,50p),(10,18p)
.model dFC51 D(CJO=308pf VJ=1.460189 M=1.378011 BV=15 IBV=100E-15)

Zener diode　RD5-24

.model drd5a D (IS=0.5uA RS=40 BV=5.00 IBV=0.5uA)
.model drd6a D (IS=0.5uA RS=30 BV=6.00 IBV=0.5uA)
.model drd7a D (IS=0.5uA RS=12 BV=7.00 IBV=0.5uA)
.model drd9a D (IS=0.5uA RS=10 BV=9.00 IBV=0.5uA)
.model drd11a D (IS=0.5uA RS=20 BV=11.00 IBV=0.5uA)
.model drd13a D (IS=0.5uA RS=25 BV=13.00 IBV=0.5uA)
.model drd16a D (IS=0.5uA RS=30 BV=16.00 IBV=0.5uA)
.model drd19a D (IS=0.5uA RS=50 BV=19.00 IBV=0.5uA)
.model drd24a D (IS=0.5uA RS=100 BV=24.00 IBV=0.5uA)

z6_8　定電圧ダイオード　ＴＲ技術　９１／６　ｐ５１５

*Vz=6.8v @ 10mA M.Okamura
.model dz6_8 D(IS=0.1f RS=.25 BV=6.8 Ibv=20u Nbv=.55 Ibv1=2.0m Nbv1=15 Cjo=175pF Vj=.75 Fc=.5 Isr=1.86n M=.55 Tbv1=-20u)

接合容量の正確なツエナーモデル

* ＴＲ技術　９１／８　ｐ５７６　容量だけ正確！
*定電圧ダイオード
.model d05z5_3 D (IS=0.5uA RS=60 BV=3.00 IBV=0.5uA CJO=186pF Vj=14.233 M=3.948)
.model d05z5_5 D (IS=0.5uA RS=40 BV=5.00 IBV=0.5uA CJO=83pF Vj=0.2539 M=0.324)
.model d05z5_75 D(IS=0.5uA RS=12 BV=7.50 IBV=0.5uA CJO=39pF Vj=2.808 M=0.753)
.model d05z5_10 D(IS=0.5uA RS=20 BV=10.0 IBV=0.5uA CJO=23pF Vj=8.0 M=1.0 )
.model d05z5_15 D(IS=0.5uA RS=30 BV=15.0 IBV=0.5uA CJO=18pF Vj=14.865 M=2.341)

接合容量の正確なLEDモデル

*ＬＥＤ　(1.6V/2mA 1.7V/10mA 1.8V/30mA)
.model dGaAlAs D(IS=6.97e-15 N=2.35 RS=1.3772 BV=15.0 IBV=0.5uA CJO=38pF Vj=0.6323 M=0.323)
*ＬＥＤ　(1.7V/1mA 1.8V/3mA 2V/14mA)
.model dGaP D(IS=7.33e-15 N=2.645 RS=1.472 BV=15.0 IBV=0.5uA CJO=19pF Vj=0.6323 M=0.322)
*過渡応答試験をした

vali200　200Vバリスタ

.model dvali200 D(IS=0.5uA RS=30 BV=200v IBV=0.5uA CJO=18pF Vj=14.865 M=2.341)

18v　1.8V limit diode

.model d18v D(IS=1e-29 RS=1 N=1.16473 BV=15.0 IBV=0.5uA CJO=19pF Vj=0.6323 M=0.322)

l3038a　レーザーマクロライブラリ

* 1=コモン、レーザー＋　2=レーザー負 3=センス電流源
.subckt dl3038a 1 2 3
.model dp D(RS=2.36 CJO=9.96pf VJ=0.9140 M=0.4199 )
*GaAlAs Type
.model dr D(IS=6.97e-15 N=2.35 RS=1.3772 BV=15.0 IBV=0.5uA
+ CJO=38pF Vj=0.6323 M=0.323)
d1 1 4 dr
rt 4 2 1
d2 3 1 dp
gp0 1 3 table {V(4,2)}= (0mV,0mA) (40mV,0mA) (100mV,1.2mA)
.ends
* End of library file

参考特性 1SS351,1N4004,1S1588,MI407,RN731V,1N60,1SS356

http://www.cqpub.co.jp/toragi/trsample/2002/tr0210/0210sn8.pdf　のグラフより

Bipola Transistor

パラメータ定義

* Library of bipolar transistor model parameters
* 既定値
*NE 1.5 低電流のｈｆｅの傾斜　小さくすると傾斜が急になる
*NC 2.0
*Eg 1.11 エネルギーギャップ　Si=1.11 Shot-key=0.69 Ge=0.67
*BF 100 中電流の時のｈｆｅを制御する
*BR 1 飽和電圧を決める(0.1-10)大きくすると飽和電圧は下がる
*ISE 0 低電流のｈｆｅの傾斜 Is の１～１．５倍で左下がりの傾向が出てくる
*IKF ∞ 大電流のｈｆｅの傾斜　半分程度下がる電流の値
*ISC 0 暗電流　Icbo
*IS 1f ベース飽和電流　BEのダイオード特性
*RB 0 ベース抵抗ベース電流の立ち上がりを制御する
* 小信号(5-50) 大電流(0.1-1)
*RE 0 エミッタ抵抗 VCE/Ic 飽和電圧を決定する
*RC 0 コレクタ抵抗小信号(0.5-5.0) 大電流(0.01-0.1)
*VAF ∞ 出力インピーダンスに相当する .OP printout on the data sheet.
* コレクタ電圧／電流の収束点への絶対電圧
* 30-100v
*CJC 0 コレクタ・ベース容量 Cobo
*CJE 0 エミッタ・ベース容量 Cibo　不明なら　1.5*CJC
*TF 0 キャリャの順方向通過時間、蓄積時間、オフ時間
* Tf = 1/(2 π Ft)　で与えてもよい（原典より） Ft=エミッタ接地hfe(f)
*TR 0 キャリャの逆方向通過時間、オン時間
*KF 0 フリッカー雑音係数　
*AF 1 フリッカー雑音指数

bip1 TTL NPNバイポーラトランジスタ

.model nbip1 npn(is=1e-17 bf=50 vaf=40 rb=150 re=14 rc=256 cje=0.07pF cjc=0.01pF cjs=0.02pF vje=0.99 vjc=0.81 vjs=0.66 tf=0.1ns tr=10ns)

2N2222A

.model Q2N2222A NPN(Is=14.34f Xti=3 Eg=1.11 Vaf=74.03 Bf=255.9 Ne=1.307
+ Ise=14.34f Ikf=.2847 Xtb=1.5 Br=6.092 Nc=2 Isc=0 Ikr=0 Rc=1
+ Cjc=7.306p Mjc=.3416 Vjc=.75 Fc=.5 Cje=22.01p Mje=.377 Vje=.75
+ Tr=46.91n Tf=411.1p Itf=.6 Vtf=1.7 Xtf=3 Rb=10)
* National pid=19 case=TO18 88-09-07 bam creation

2N2907

.model Q2N2907 PNP(Is=9.913f Xti=3 Eg=1.11 Vaf=90.7 Bf=197.8 Ne=2.264
+ Ise=6.191p Ikf=.7322 Xtb=1.5 Br=3.369 Nc=2 Isc=0 Ikr=0 Rc=1
+ Cjc=14.57p Vjc=.75 Mjc=.3333 Fc=.5 Cje=20.16p Vje=.75
+ Mje=.3333 Tr=29.17n Tf=405.6p Itf=.4 Vtf=10 Xtf=2)

2N2907A

.model Q2N2907A PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=231.7 Ne=1.829
+ Ise=54.81f Ikf=1.079 Xtb=1.5 Br=3.563 Nc=2 Isc=0 Ikr=0 Rc=.715
+ Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75
+ Tr=111.3n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
* National pid=63 case=TO18 88-09-09 bam creation

2N3904

.model Q2N3904 NPN(Is=6.734f Xti=3 Eg=1.11 Vaf=74.03 Bf=416.4 Ne=1.259
+ Ise=6.734f Ikf=66.78m Xtb=1.5 Br=.7371 Nc=2 Isc=0 Ikr=0 Rc=1
+ Cjc=3.638p Mjc=.3085 Vjc=.75 Fc=.5 Cje=4.493p Mje=.2593 Vje=.75
+ Tr=239.5n Tf=301.2p Itf=.4 Vtf=4 Xtf=2 Rb=10)
* National pid=23 case=TO92 88-09-08 bam creation

2N3906

.model Q2N3906 PNP(Is=1.41f Xti=3 Eg=1.11 Vaf=18.7 Bf=180.7 Ne=1.5 Ise=0
+ Ikf=80m Xtb=1.5 Br=4.977 Nc=2 Isc=0 Ikr=0 Rc=2.5 Cjc=9.728p
+ Mjc=.5776 Vjc=.75 Fc=.5 Cje=8.063p Mje=.3677 Vje=.75 Tr=33.42n
+ Tf=179.3p Itf=.4 Vtf=4 Xtf=6 Rb=10)
* National pid=66 case=TO92 88-09-09 bam creation

2SA817

.model Q2SA817 PNP(Bf=120 Br=1 Is=88f Eg=1.11 Cjc=34p Cje=70p Vaf=100
+ Tf=1.553n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SA952

.model Q2SA952 PNP(Bf=200 Br=1 Is=83f Eg=1.11 Cjc=4.8p Cje=10p Vaf=50
+ Tf=0.988n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SA1015　Low Noise Complementary 2SC1815

*Low Noise Amp PC=0.4W Ic=0.15A Vcbo=50V Complementary 2SC1815
.model Q2SA1015 PNP(Is=295.1E-18 Xti=3 Eg=1.11 Vaf=100 Bf=110 Ne=1.5 Ise=0
+ Ikf=0 Xtb=1.5 Br=10.45 Nc=2 Isc=0 Ikr=0 Rc=15 Cjc=66.2p
+ Mjc=1.054 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=1.661n Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-23 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SA1015.pdf

2SA1016

*Low Noise HighVoltage PC=0.4W Ic=0.1A Vcbo=100V Complementary 2SC2362 SANYO
.model 2SA1016 PNP(Bf=110 Br=10 Cjc=2.2p cje=5p RB=20 RC=5 Tr=150n Tf=10n)

2007/04/19 Hal.T　SW試験で決定
2SA1016_2SC2362.pdf　2SA1016.asc

Q2SA1048

*Low Noise Amp PC=0.2W Ic=0.05A Vcbo=50V
.model Q2SA1048 PNP(Is=295.1E-18 Xti=3 Eg=1.11 Vaf=100 Bf=110 Ne=1.5 Ise=0
+ Ikf=0 Xtb=1.5 Br=10.45 Nc=2 Isc=0 Ikr=0 Rc=15 Cjc=66.2p
+ Mjc=1.054 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=1.661n Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-23 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SA1049

*Low Noise Amp PC=0.2W Ic=0.1A Vcbo=120V
.model Q2SA1049 PNP(Is=350.8n Xti=3 Eg=1.11 Vaf=40 Bf=350 Ne=1.5 Ise=0 Ikf=0
+ Xtb=1.5 Br=.7978 Nc=2 Isc=0 Ikr=0 Rc=4 Cjc=12.26p Mjc=.3652
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=1.305n Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-23 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SA1145

.model Q2SA1145 PNP(Is=173.9p Eg=1.11 Vaf=60 Bf=110 Br=1 Nc=2 Cjs=2p
+ Cjc= 6.02p Mjc=.330 Vjc=.75 Cje=1p Mje=.33 Vje=.75 Tr=10n Tf=0.788n)
* CQ 1988/7　より引用

2SA1179

2SA1179_2SC2812.pdf

2SA1298

.model Q2SA1298 PNP(Is=141f Xti=3 Eg=1.11 Vaf=20 Bf=230 Ne=1.5 Ise=0 Ikf=.7
+ Xtb=1.5 Br=14.57 Nc=2 Isc=0 Ikr=0 Rc=1 Cjc=622.4p Mjc=1.453
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=1.205n Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-26 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SA1313

.model Q2SA1313 PNP(Is=14.1f Xti=3 Eg=1.11 Vaf=100 Bf=150 Ne=1.5 Ise=0 Ikf=.8
+ Xtb=1.5 Br=3.338 Nc=2 Isc=0 Ikr=0 Rc=.6 Cjc=59.01p Mjc=.6885
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=766.1p Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-23 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SA1606

2SA1606_2SC4159.pdf

２SA1683

2SA1683_2SC4414.pdf

2SA1731

*Low Noise HighVoltage PC=1W Ic=5A Vcbo=50V
.model 2SA1731 PNP(Bf=100 Rc=1 Cjc=60p RB=20 Cje=100p Tr=1u Tf=50n)
* SANYO Pulse Use Hal.T 2007/04/19　　SW試験で決定
2SA1731.pdf　2SA1731.asc

2SB595

.model Q2SB595 PNP(Bf=55 Br=1 Is=83f Eg=1.11 Cjc=4.8p Cje=10p Vaf=100
+ Tf=1.923n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SB631

2SB631_2SD600.pdf

2SB688

.model Q2SB688 PNP(Bf=70 Br=1 Is=73f Eg=1.11 Cjc=4.8p Cje=10p Vaf=100
+ Tf=1.923n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SB764

2SB764_2SD863.pdf

2SB799

.model Q2SB799 PNP(Is=15.01f Xti=3 Eg=1.11 Vaf=70 Bf=199.4 Ne=1.112
+ Ise=164.6E-18 Ikf=2 Xtb=1.5 Br=9.83 Nc=2 Isc=0 Ikr=0 Rc=.001
+ Cjc=58.04p Mjc=.3818 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75
+ Tr=10n Tf=1.084n Itf=0 Vtf=0 Xtf=0)
* NEC 89-12-08 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SB800

.model Q2SB800 PNP(Is=62.26f Xti=3 Eg=1.11 Vaf=2 Bf=370 Ne=1.01
+ Ise=8.673E-18 Ikf=50m Xtb=1.5 Br=13.28 Nc=2 Isc=0 Ikr=0 Rc=.4
+ Cjc=26.22p Mjc=.3197 Vjc=.75 Fc=.5 Cje=42.32p Mje=.4061 Vje=.75
+ Tr=10n Tf=1.342n Itf=0 Vtf=0 Xtf=0)
* NEC 89-12-08 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SC288

.model Q2SC288 NPN(Bf=70 CJC=0.7pF CJE=1.0pF Rb=15 Rc=3 Tr=0.2n Tf=0.2n)
*ＣＱトランジスタ規格表よりの推定 Cob=0.7pf Cc.rbb=10ps hfe=70 @ 6v,2mA
*　私が作ったいいかげんなものだと思う

2SC945

.model Q2SC945 NPN(Bf=150 Br=1 Is=180.4p Eg=1.11 Cjc=6.4p Cje=20p Vaf=50
+ Tf=.6041n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC980A

.model Q2SC980A NPN(Bf=140 Br=1 Is=229.6p Eg=1.11 Cjc=6.6p Cje=20p Vaf=50
+ Tf=.6039n Tr=49n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC1627

.model Q2SC1627 NPN(Bf=140 Br=1 Is=0.174p Eg=1.11 Cjc=24p Cje=1p Vaf=150
+ Tf=1.503n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC1675

.model Q2SC1675 NPN(Bf=100 Br=1 Is=1.771f Eg=1.11 Cjc=4.5p Cje=1p Vaf=100
+ Tf=0.432p Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC1781

.model Q2SC1781 NPN(Is=3.108f Xti=3 Eg=1.11 Vaf=30.0 Bf=100 Ne=1.541
+ Ise=190.7f Ikf=1.296 Xtb=1.5 Br=6.18 Nc=2 Isc=0 Ikr=0 Rc=1
+ Cjc=18p Vjc=.75 Mjc=.3333 Fc=.5 Cje=65p Vje=.75
+ Mje=.3333 Tr=35n Tf=6n Itf=1 Vtf=100 Xtf=2)
*　来歴不明

2SC1815 Complementary 2SA1015

*Low Noise Amp PC=0.4W Ic=0.15A Vcbo=60V Complementary 2SA1015
.model Q2SC1815 NPN(Is=2.04f Xti=3 Eg=1.11 Vaf=6 Bf=400 Ne=1.5 Ise=0
+ Ikf=20m Xtb=1.5 Br=3.377 Nc=2 Isc=0 Ikr=0 Rc=1 Cjc=1p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=25p Mje=.3333 Vje=.75 Tr=450n Tf=20n Itf=0 Vtf=0 Xtf=0)

2008/04/08 Hal.T
trg 1993/07 page 403 SW実験にあわせた、SW時間は正確、ベースになった情報が不明なので、SW時間以外はいいかげん。
2SC1815.pdf
2SC1815.asc (@LT-SPICE）この回路にてコレクタ側立ち上がりを2-3usecに tr,tf　を調整した

2SC1907

.model Q2SC1907 NPN(Is=1.00f Xti=3 Eg=1.11 Vaf= 40 Bf=350
+ Ikf=150m Nk=0.995 Ise= 90f Ne=1.5 Xtb=1.5 Br=.1 Nc=2 Isc=0 Ikr=0
+ Cjc=3p Cje=5p Rb=10 Rc=2 Tr=1n Tf=0.250n Itf=0 Vtf=0 Xtf=0)
* Hitachi EP UHF-amp,mix,osc　私が作ったいいかげんなものだと思う、すでに来歴不明

2SC1959

.model Q2SC1959 NPN(Is=14.1f Xti=3 Eg=1.11 Vaf=100 Bf=180 Ne=1.5 Ise=0 Ikf=.8
+ Xtb=1.5 Br=3.338 Nc=2 Isc=0 Ikr=0 Rc=4 Cjc=59.01p Mjc=.6885
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=766.1p Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-23 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SC2003

.model Q2SC2003 NPN(Bf=200 Br=1 Is=57.6f Eg=1.11 Cjc=17p Cje=47p Vaf=50
+ Tf=1.059n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC2240

*TOSHIBA
.model Q2SC2240 NPN(Is=1.41f Xti=3 Eg=1.11 Vaf=100 Bf=310 Ne=1.5 Ise=0
+ Ikf=70m Xtb=1.5 Br=.8893 Nc=2 Isc=0 Ikr=0 Rc=30 Cjc=6.878p
+ Mjc=.2725 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=1.276n Itf=0 Vtf=0 Xtf=0)

私が作ったいいかげんなものだと思う、すでに来歴不明

2SC2362

*Low Noise Amp PC=400mW Ic=50mA Vcbo=120V Complementary 2SA1016 SANYO
.model 2SC2362 NPN(Bf=250 br=7 Rc=100 Cjc=1.8p Cje=5p Tr=0.4u Tf=10n)

2007/04/13 for Pulse AMP Tr,TFだけそれなり Hal.T　SW試験による
2SC2362.asc

2SC2668

.model Q2SC2668 NPN(Bf=350 Br=1 Is=1.00f Eg=1.11 Cjc=15p Cje= 1p Vaf=100
+ Tf=3.612n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC2669

.model Q2SC2669 NPN(Bf=100 Br=1 Is=1.59e-20 Eg=1.11 Cjc= 7p Cje=49p Vaf=100
+ Tf=0.883n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC2754

.model Q2SC2754 NPN(Bf=180 Br=1 Is=8.321f Eg=1.11 Cjc=4.8p Cje= 1p Vaf=100
+ Tf=0.391n Tr=.48u Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC3279

.model Q2SC3279 NPN(Bf=180 Br=1 Is=1.217n Eg=1.11 Cjc=65p Cje=1p Vaf=100
+ Tf=1.060n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC3358

.model Q2SC3358 NPN(Bf=120 Br=1 Is=16f Eg=1.11 Cjc=0.5p Cje=0.75p Vaf=200
+ Tf=23p Tr=2n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=1p )
* トランジスタ規格表より Cre=0.5pf(帰還容量）　hfe(DC)=120 @20mA fT=7GHz

2SC3378

.model Q2SC3378 NPN(Bf=300 Br=1 Is=695p Eg=1.11 Cjc=7.7p Cje=1p Vaf=200
+ Tf=1.252n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SC4522

2SC4522.pdf

2SC4523

*Low Noise Amp PC=1W Ic=8A Vcbo=60V SANYO
.model 2SC4523 NPN(Bf=100 br=5 rb 5 Rc=1 Cjc=65p Cje=100p Tr=0.40u Tf=0.1u)

2007/04/13 for Pulse AMP Tr,TFだけそれなり Hal.T　SW試験による
2SC4523.asc
SC4523.pdf

2SD525

.model Q2SD525 NPN(Bf= 60 Br=1 Is=254.3p Eg=1.11 Cjc=241p Cje=1p Vaf=50
+ Tf=13.26n Tr=10n Mjc=.330 Vjc=.75 Mje=.33 Vje=.75 Cjs=2p )
* CQ 1988/7　より引用

2SD1007

.model Q2SD1007 NPN(Is=15.01f Xti=3 Eg=1.11 Vaf=100 Bf=214 Ne=2.726 Ise=266.1p
+ Ikf=.5 Xtb=1.5 Br=77.03 Nc=2 Isc=0 Ikr=0 Rc=5 Cjc=31.21p
+ Mjc=.4128 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=988.1p Itf=0 Vtf=0 Xtf=0)
* NEC 89-12-14 creation　　私が作ったいいかげんなものだと思う、すでに来歴不明

2SD1588

.model Q2SD1588 NPN(Is=6.467E-18 Xti=3 Eg=1.11 Vaf=100 Bf=500k Ne=4.522
+ Ise=57.25n Ikf=100u Xtb=1.5 Br=3.474K Nc=2 Isc=0 Ikr=0
+ Rc=50m Cjc=2p Mjc=.3333 Vjc=.75 Fc=.5 Cje=5p Mje=.3333
+ Vje=.75 Tr=10n Tf=1n Itf=0 Vtf=0 Xtf=0)
* NEC 90-01-11 creation　私が作ったいいかげんなものだと思う、すでに来歴不明

2SD1940

2SD1940.pdf

FET

パラメータ定義

* 大電流の用途に使う場合は直列インダクタンスをソース、ドレインに入れる
* とよい結果が得られる
* 不明な場合は１ｍｍあたり１ｎＨ
* TO-204 (modified TO-3) source = 12.5nH drain = 5.0nH
* TO-220 source = 7.5nH drain = 3.5-4.5nH
*-----------------------------------------------------------------
*ＭＯＳ－ＦＥＴのパラメータ
*
*level 1 平均２乗特性（既定値）
* (2) 短チャンネル・デバイス効果を考慮した lebel1 の精密解
* (3) 実測データによるカーブ・フィッティングによる準経験的モデル
* ２μ程度の素子によく合わせることができる
*
*level 1,2,3
*vto 0 直線外挿したカットオフ電圧
*kp 20uトランス・コンダクタンス
*gammma 0 バックゲートによる vto 変調係数
*cgso 0 ゲート・ソース・オーバーラップ容量
*cgdo 0 ゲート・ドレイン・オーバーラップ容量
*cgbo 0 ゲート・バルク・オーバーラップ容量
*l 100u .options DEFL で定義される
* 1u　程度まで小さくするとｋｐの飽和が現れる
*w 100u .options DEFW で定義されるチャンネル巾
* 大きくすると並列に見える＝kp が大きく見える
*
*level 1 -----------------------
*lambda 0 チャンネル長変調係数　Vds　を増加させたときの出力コンダクタンス
* bjtのvafに相当する効果 ids/vds のカーブを水平から右上がりにする
* Vaf の逆数と考えてもよい

*level 3 ------------------------
*eta 0 アーリー効果に相当、ids/vds のカーブを水平から右上がりにする
*delta 0 チャンネル巾ファクタ
*kappa 0.2
*theta 0 小さくすると kp ２乗特性を示す
*
*-----------------------------------------------------------------
*Ｊ－ＦＥＴのパラメータ
*vto -2.0 スレッショルド電圧
*beta 10mS 相互コンダクタンス
*lambda 0 チャンネル長変調係数
*rd 0 ドレイン抵抗
*rs 0 ソース抵抗
*cgs 0 ゲート・ソース接合容量
*cgd 0 ゲート・ドレイン接合容量
*pb 1 ゲート接合ポテンシャル
*is 10f ゲート接合飽和電流

IRF150

* IRF150, from 1985 Siliconix databook, pages 1-7,8 and 5-22,3
.model IRF150 NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
+ Tox=100n Uo=600 Phi=.6 Rs=5.724m Kp=20.76u W=.31 L=2u
+ Vto=2.759 Rd=2.6m Rds=400K Cbd=4.039n Pb=.8 Mj=.5 Fc=.5
+ Cgso=8.984n Cgdo=1.62n Rg=18.6 Is=648.2E-18)

IRF9130

* IRF9130, from 1985 International Rectifier databook, pages D-187,92
.model IRF9130 PMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
+ Tox=100n Uo=300 Phi=.6 Rs=.1429 Kp=9.899u W=1.1 L=2u
+ Vto=-3.418 Rd=74.02m Rds=400K Cbd=407.7p Pb=.8 Mj=.5 Fc=.5
+ Cgso=1.996n Cgdo=147p Rg=8.696 Is=1E-30)

IC nmos

.model cmosn nmos(level=1 vto=0.5 kp=35.2e-6 gamma=0.91
+ cgso=210pF cgdo=210pF cj=4.9e-4 cjsw=245pF ld=3e-7 pb=0.94 tox=50n)

IC pmos

.model cmosp pmos(level=1 vto=0.5 kp=13.4e-6 gamma=0.64
+ cgso=210pF cgdo=210pF cj=2.3e-4 cjsw=117pF ld=3e-7 pb=0.90 tox=50n)

2N4416A

.model J2N4416A NJF(Beta=1m Betatce=-.5 Rd=9 Rs=9 Lambda=5m Vto=-3
+ Vtotc=-2.5m Is=50f Isr=1.3p N=1 Nr=2 Xti=3 Alpha=8u Vk=104 Cgd=1.5p M=.5 Pb=1 Fc=.5 Cgs=5p)
*CQ 91/7 M.Okamura RF-junkciotn FET

2SJ652

*2SJ652 SANYO
.model 2SJ652 PMOS(Level=1
+ Rd=20m Rs=20m Rg=15 Kp=1m l=1u W=0.2 Vto=-2.300 Cgso=4300p Cgdo=500p)

Hal.T 2007/04　大電流SW用途のためにデータシートから作成、それなりに使える
2SJ652.pdf　2SJ652J.pdf　2SJ652DC.asc

2SK19

*2SK19 だいたいもいいところ
.model J2SK19 NJF(vto=-2.0v beta=7.00m lambda=0 cgd=5.0p cgs=2.3p rd=10 rs=10

2SK30

*2SK30 id(R 0.3-0.75 / O 0.6-1.4 / Y 1.2-3.00 / GR 2.6-6.5)
.model J2SK30r NJF(vto=-0.8v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p dev 10% LOT 60%)
.model J2SK30o NJF(vto=-1.1v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p dev 10% LOT 60%)
.model J2SK30y NJF(vto=-1.8v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p dev 10% LOT 60%)
.model J2SK30gr NJF(vto=-2.8v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p dev 10% LOT 60%)
.model J2SK30atm NJF(beta=.768m vto=-2.70 cgd=2.6p cgs=8.2p dev 10% LOT 60%)
* CQ 1988/7　より引用

2SK83S1

.model J2SK83S1 NJF(beta=4.0m vto=-1.0 cgd=0.1p cgs=4.0p rd=10 rs=10, lambda=0.01)
*82 CQ FET Manual

2SK117

.model J2SK117 NJF(beta=13.1m vto=-0.70 cgd= 3p cgs=13p)
* CQ 1988/7　より引用

2SK147

.model J2SK147 NJF(beta=136m vto=-0.38 cgd=15p cgs=75p)
* CQ 1988/7

2SK161

.model J2SK161 NJF(beta=4.34m vto=-1.40 cgd=.15p cgs=3.9p dev 10% LOT 60%)
* CQ 1988/7　より引用

2SK192A

.model J2SK192A NJF(beta=2.96m vto=-2.60 cgd= 1p cgs= 2p)
* CQ 1988/7　より引用

2SK241

*2SK241 1992/1/15
.model M2SK241 NMOS(Level=1 Xj=0 Rd=25 Rs=25 Rg=50 Kp=10m
+ Vto=-1.50 Mj=.5 Fc=.5 Cbd=3p Cbs=3p Cgso=3.0p Cgdo=0.04p)

2SK246

.model J2SK246 NJF(beta=1.63m vto=-2.50 cgd=2.5p cgs= 9p)
* CQ 1988/7　より引用

2SK372

.model J2SK372 NJF(beta=112m vto=-0.40 cgd=15p cgs=600p)
* CQ 1988/7　より引用

2SK373

.model J2SK373 NJF(beta=3.98m vto=-1.60 cgd= 3p cgs=13p)
* CQ 1988/7　より引用

2SK408 & 409

*2SK408 & 409
.model M2SK408 NMOS(Level=3 Gamma=0 Delta=0 Eta=0.00 Theta=1 Kappa=0 Vmax=0
+ Xj=0 Rd=2.5 Rs=2.5 Rg=5 Kp=25u l=2u W=1 Tox=700n Uo=600 Phi=.6
+ Vto=1.700 Pb=.8 Mj=.5 Fc=.5 Cbd=200p Cbs=200p Cgso=0.3p Cgdo=0.2p Is=6E-18)

HFリニアアンプの製作の為に使った、RF出力段の回路試験用としてそこそこ良いモデル
http://www.madlabo.com/mad/edat/hj58AMP/hj58amp.htm

2SK3702

2SK3702.pdf

2SK3704

*SANYO
.model 2SK3704 NMOS(Level=1
+ Rd=10m Rs=10m Rg=15 Kp=1m l=1u W=0.2 level=2
+ Vto=2.700 Cgso=5500p Cgdo=500p cgbo=500p)

2007/04 Hal.T　中電流SW実験により作成
2SK3704.pdf　2SK3704DC.asc　2SK3704Tran.asc　2SK3704.asc

EC4K01KF

Pch MOS コンデンサマイクロフォン用　SANYO
EC4K01KF.pdf
EC4K01KF.lib　EC4K01KF_AC.asc　EC4K01KF_DC.asc　2009/01/10 Hal.T

TF252TH

N-ch　接合型FET　発振回路として使用　SANYO
TF252TH.pdf
TF252TH.lib
TF252TH_AC.asc　TF252TH_DC_IdVds.asc　TF252TH_DC_IdVgs.asc
TF252TH_ RFOSC1.asc　TF252TH_ RFOSC2.asc　TF252TH_ RFOSC3.asc 　2009/01/10 Hal.T

マクロモデル

OP-AMP

*-----------------------------------------------------------
*理想オペアンプ
*-----------------------------------------------------------
*オペアンプ　１２０dB　入力抵抗 1G
*-----------------------------------------------------------
* + - out
.subckt opamp 1 2 3 params: adb = 120
rin 1 2 1G
eout 3 0 value = { v(1,2)*pwr(10,adb/20) }
rout 3 0 1G
.ends
*-----------------------------------------------------------
*オペアンプ　１２０dB　入力抵抗 1G　電源制限
*-----------------------------------------------------------
* + - V+ V- out
.subckt opamp1 1 2 3 4 5 params: adb = 120, pi=3.14
rin 1 2 1G
eout 5 0 value={atan(pi*v(1,2)*pwr(10,adb/20)/v(3,4))*v(3,4)/pi-v(4)/2}
rpow 3 4 1G
.ends
*-----------------------------------------------------------

π型共振回路用のＶＣ

*-----------------------------------------------------------
*共振周波数へ追随するπ型共振回路用のＶＣ　２連ＶＣのタイプ。　.AC　では使える
*-----------------------------------------------------------
.subckt vc2 1 2 params: l=2.53uH
g0 1 2 laplace {v(1,2)} = { -2/(l*s) }
.ends
*-----------------------------------------------------------
*共振周波数へ追随するπ型共振回路用のＶＣ　片方だけがＶＣのタイプ。　.AC　では使える
* in=ca0 coil=ld out=このVC1
*-----------------------------------------------------------
.subckt vc1 1 2 params: l=2.53uH cin=200pF
g0 1 2 laplace {v(1,2)} = { -(cin*s)/(cin*l*s*s+1) }
.ends

ダイポールアンテナ

*-----------------------------------------------------------
*ダイポールアンテナ
*１０ＭＨＺ　φ＝３ｍｍ　Ｌ＝０．２４７λで計算した値による
*８ＭＨｚ～１２ＭＨｚで傾向は一致している
*中心周波数の共振などの用途に使うことしかできない
*title ＤＰ　１０ＭＨｚ
* 13.000000 MHz 166.736 717.730
* 12.000000 MHz 123.168 452.827
* 11.000000 MHz 92.002 218.536
* 10.000000 MHz 68.942 -4.240
* 9.000000 MHz 51.455 -225.198
* 8.000000 MHz 37.967 -459.851
* 7.000000 MHz 27.458 -717.871
* 6.000000 MHz 19.245 -1020.947
*-----------------------------------------------------------
.subckt dp0 1 2 params: f =10Meg
rd0 1 2 1Meg
cs 1 10 { 1/(1250*6.28*f) }
ls 10 2 { 1254/(6.28*f) }
rs 10 2 22714
.ends

３素子八木アンテナ

*-----------------------------------------------------------
* yag3 21MHzいい加減３素子八木アンテナ
*21MHz　φ＝32mm
*20MHz-22.4MHz でシミュレーション出来る
*中心周波数の共振などの用途に使うことしかできない
* MHz R j
* 20.0 16.27 -56.01
* 20.2 17.10 -47.13
* 20.4 16.88 -39.26
* 20.6 15.19 -31.23
* 20.8 12.51 -22.12
* 21.0 9.59 -11.64
* 21.2 7.01 0.1
* 21.4 5.14 12.81
* 21.6 4.18 26.99
* 21.8 4.19 39.93
* 22.0 5.13 53.76
* 22.2 6.92 67.49
* 22.4 9.41 80.99
*-----------------------------------------------------------
.subckt yag3 1 2 params: f =21.2Meg
vs 1 3 0v
rd 4 2 1
ey3 3 4 freq { i(vs) } =
+(20.0Meg,58.3252,-73.8022)
+(20.2Meg,50.1362,-70.0579)
+(20.4Meg,42.7350,-66.7345)
+(20.6Meg,34.7282,-64.0621)
+(20.8Meg,25.4124,-60.5096)
+(21.0Meg,15.0816,-50.5155)
+(21.2Meg,7.01071,0.817287)
+(21.4Meg,13.8027,68.1369)
+(21.6Meg,27.3117,81.1964)
+(21.8Meg,40.1492,84.0096)
+(22.0Meg,54.0042,84.5491)
+(22.2Meg,67.8438,84.1457)
+(22.4Meg,81.5348,83.3726)
.ends

電圧可変抵抗

*-----------------------------------------------------------
*(1,2)制御電圧 (4,5)制御出力(R,L,C)
*(1,2) = (4,5) * param　となる　v1は掛け率が１となる電圧
*-----------------------------------------------------------
.subckt vr0 1 2 4 5 params: vs=1.0v rs=1
rin 1 2 1G
rse 4 7 1n ;ダミーの直列抵抗
eout 7 6 value = { v(1,2)*v(3,0)/vs }
fcop 0 3 vsen 1
vsen 6 5 0
rs0 3 0 { rs }
.ends

電圧可変インダクタンス

*------------------------
*(1,2)制御電圧 (4,5)制御出力(R,L,C)
*(1,2) = (4,5) * param　となる　v1は掛け率が１となる電圧
*------------------------
.subckt vl0 1 2 4 5 params: vs=1.0v ls=1uH
rin 1 2 1G
rse 4 7 1n ;ダミーの直列抵抗
eout 7 6 value = { v(1,2)*v(3,0)/vs }
fcop 0 3 vsen 1
vsen 6 5 0
ls0 3 0 { ls }
.ends

電圧可変キャパシタンス（容量）

*------------------------
*(1,2)制御電圧 (4,5)制御出力(R,L,C)
*(1,2) = (4,5) * param　となる　v1は掛け率が１となる電圧
*------------------------
.subckt vc0 1 2 4 5 params: vs=1.0v cs=1uF init=0
rin 1 2 1G
ecop 3 6 value = { v(1,2)*v(4,5)/vs }
fout 4 5 vsen 1
vsen 0 6 0
cs0 3 0 { cs } ic={ init }
.ends

単層巻のコイル　 .AC でしか使えない

*-----------------------------------------------------------
*単層巻のコイル Rac は周波数の√に比例して増加する
* H=インダクタンス F,Q=ある周波数でのＱ
* L+R(f) の直列形式、並列容量は無視される
* .AC でしか使えない
*-----------------------------------------------------------
.subckt LQ0 t0 t1 params: h=2.53uH f0=10Meg, q=80
l00 200 t1 { h } ;インダクタンス
ri0 t0 100 1m ;直列抵抗のダミー
rp0 100 200 1G ;並列抵抗のダミー
gr0 100 200 value = { v(20)*q/80*f0/10Meg } ;実効抵抗
rp1 20 0 1G ;並列抵抗のダミー
er0 20 0 freq {v(t0,200)} = ;係数の算出
+ ( 0, 13, 0) ;DC
+ ( 150k, 12, 0)
+ ( 10Meg, -6, 0)
+ (100Meg, -16, 0)
+ ( 1G , -26, 0)
+ ( 10G , -36, 0)
.ends

単層巻のコイル　 .tran で使える

*-----------------------------------------------------------
*単層巻のコイル Rac 　周波数の√に比例して増加する
* h 　　インダクタンス
* f0 Ｑを設定する周波数
* f1 動作させる　周波数
* L+R(f) の直列形式、並列容量は無視される
* 動作させる周波数では計算されたＱをもつ。
* .tran で使えるが .AC では不正確（抵抗分をあらかじめ計算するため）
*-----------------------------------------------------------
.subckt lq1 t0 t1 params: h=2.53uH f0=10Meg q=80 f1=10Meg ic0=0mA
l00 t0 10 { h } ic={ ic0 } ;インダクタンス
rd0 10 t1 { (6.2832*f0*h)/q*sqrt(f1/f0) }
.ends

３極菅　6C4

*-----------------------------------------------------------
*　３極菅　gm=5m moh μ=10 Rp=20K
*-----------------------------------------------------------
.subckt 6C4 P G K
*G K model
g_gk g k table {v(g,k)} = (-1, 0) (0, 0.1m) (1, 1m) (2,3m)
e_ef 1 0 table {v(g,k)+v(p,k)/10} = (0, 0) (1k, 1k)
r_ef 1 0 100meg ;dumy
g_pk p k value = { 0.5m*pwr(v(1),1.5) }
c_gk g k 10p
c_pg p g 10p
c_pk p k 5p
.ends

Xtal

*-----------------------------------------------------------
*水晶振動子 Xtal Fs=直列共振 Fp=並列共振-Fs Q = ZL/R
*-----------------------------------------------------------
* 例
* (TR 1984/8 p409) 10MHz cp=5.7pf Rs=10 Cs=0.025p Ls=10mH
*”周波数と時間”電子情報通信学会 p70 5MHz cp=4pf Rs=120 Cs=0.11fF Ls=9H
* Q=2.3Meg
* Fs を直列共振周波数　Fd を並列共振周波数への距離　Cp を並列容量とする
.subckt Xtal t0 t1 params: Fs=9.999Meg Fd=1k Q=1000000 Cp=5.7pF
cp0 t0 t1 { Cp }
rs0 t1 10 { fs/(2*3.141516*Cp*Fd*Q*(Fd+2*Fs)) }
cs0 10 20 { cp*fd*(fd+2*fs)/(fs*fs) }
ls0 20 t0 { 1/(4*9.86960*cp*fd*(fd+2*fs)) }
rlek t0 t1 100Meg ;Leakage
.ends

ノイズフィルタ

*-----------------------------------------------------------
*T=巻数　N＝重ね合わせ数　noise filter
*-----------------------------------------------------------
*noise filter FT82 #43　
.subckt NFT82_43 ina inb outa outb params: T=5 N=1
L00 ina 5 { 557nH * T*T*N }
L01 inb 6 { 557nH * T*T*N }
K00 L00 L01 0.999
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends

伝送線路トランス

*-----------------------------------------------------------
*T=巻数　N＝重ね合わせ数　伝送線路の遅延係数は√２ p85 トロイダルコア活用法
*-----------------------------------------------------------
*伝送線路トランス FT82 #43　
.subckt KFT82_43 ina inb outa outb params: T=5 N=1
L00 ina 5 { 557nH * T*T*N }
L01 inb 6 { 557nH * T*T*N }
K00 L00 L01 0.99999
T 5 6 outa outb z0=150 td={ (21*T-14)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends
*-----------------------------------------------------------
*伝送線路トランス FT82 #61　
* T=巻数 N=コアの数
*-----------------------------------------------------------
.subckt KFT82_61 ina inb outa outb params: T=5 N=1
L00 ina 5 { 80nH * T*T*N }
L01 inb 6 { 80nH * T*T*N }
K00 L00 L01 0.99999
T 5 6 outa outb z0=150 td={ (21*T-14)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends
*-----------------------------------------------------------
*伝送線路トランス FT50 #61　0.3mm twist 5turn(85mm)=0.283nsec
* T=巻数 N=コアの数
*-----------------------------------------------------------
.subckt KFT50_43 ina inb outa outb params: T=5 N=1
L00 ina 5 { 523nH * T*T*N }
L01 inb 6 { 523nH * T*T*N }
K00 L00 L01 0.99999
T 5 6 outa outb z0=150 td={ (20*T-12)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends
*-----------------------------------------------------------
*伝送線路トランス FT50 #61　0.3mm twist 5turn(85mm)=0.283nsec
* T=巻数 N=コアの数
*-----------------------------------------------------------
.subckt KFT50_61 ina inb outa outb params: T=5 N=1
L00 ina 5 { 68nH * T*T*N }
L01 inb 6 { 68nH * T*T*N }
K00 L00 L01 0.99999
T 5 6 outa outb z0=150 td={ (20*T-12)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends
*-----------------------------------------------------------
*伝送線路トランス FB801 #43 8mm AL=1565nH/T^2 T=巻数 N=コアの数
*-----------------------------------------------------------
.subckt KFB801 ina inb outa outb params: T=5 N=1
L00 ina 5 { 1565nH * T*T*N }
L01 inb 6 { 1565nH * T*T*N }
K00 L00 L01 0.99999
T 5 6 outa outb z0=150 td={ (20*T-12)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends
*-----------------------------------------------------------
*伝送線路トランス FB101 #43 3　ビーズ型 T=巻数 N=コアの数
*-----------------------------------------------------------
.subckt KFB101 ina inb outa outb params: T=5 N=1
L00 ina 5 { 609nH * T*T*N }
L01 inb 6 { 609nH * T*T*N }
K00 L00 L01 0.99999
T 5 6 outa outb z0=150 td={ (9*T-3)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
C01 ina inb 1pF
C02 5 6 1pF
.ends
*-----------------------------------------------------------
*３本巻の伝送線路風トランス FB101 #43 3　ビーズ型 T=巻数 N=コアの数
*-----------------------------------------------------------
.subckt KFB101-3 ina inb inc outa outb outc params: T=5 N=1
L00 ina 5 { 609nH * T*T*N }
L01 inb 6 { 609nH * T*T*N }
L02 inc 7 { 609nH * T*T*N }
K00 L00 L01 L02 0.999
T0 5 0 outa 0 z0=150 td={ (9*T-3)/300/0.7*N*1n }
T1 6 0 outb 0 z0=150 td={ (9*T-3)/300/0.7*N*1n }
T2 7 0 outc 0 z0=150 td={ (9*T-3)/300/0.7*N*1n }
L10 5 outa .1uH
L11 6 outb .1uH
L12 7 outc .1uH
C00 ina inb 1pF
C01 inb inc 1pF
C02 ina inc 1pF
C10 5 6 1pF
C11 6 7 1pF
C12 5 7 1pF
.ends
*-----------------------------------------------------------
*Dousou トランス H = mH M=ketugou
*-----------------------------------------------------------
.subckt KDT ina inb outa outb params: H=30mH M=0.999
L00 ina 5 { H }
L01 inb 6 { H }
K00 L00 L01 { M }
L10 5 outa 1uH ;zanryuu induct
L11 6 outb 1uH
C01 ina inb 10pF ;float capacita
C02 5 6 10pF
.ends

サンプルホルド

*------------------------
* サンプルホルド
*------------------------
* clk in out
.subckt sh clk in out
ein 10 0 value = { v(in) }
.model shsw vswitch(RON=1, ROFF=1G, VON=1, VOFF=0)
sw1 10 12 clk 0 shsw
chld 12 0 1p
eout out 0 value = { v(12) }
rout out 0 1G
.ends

サンプルホルド＋シフトレジスタのパーツ

*------------------------
* サンプルホルド＋シフトレジスタのパーツ
*------------------------
* clk in+ out
.subckt shp 3 1 2
ein 10 0 value = { v(1) }
.model shsw1 vswitch(RON=1, ROFF=1G, VON=0 , VOFF=0.25)
.model shsw2 vswitch(RON=1, ROFF=1G, VON=1 , VOFF=0.75)
sw1 10 12 3 0 shsw2
chl1 12 0 100p
;e1 20 0 value = { v(12) }
sw2 12 22 3 0 shsw1
chl2 22 0 0.1p
e2 2 0 value = { v(22) }
rd 2 0 1G
.ends
*------------------------
* 4 段サンプルホルド
*------------------------
* clk in+ out...
.subckt sh4 1 2 3 4 5 6
x1p 1 2 3 shp
x2p 1 3 4 shp
x3p 1 4 5 shp
x4p 1 5 6 shp
.ends

TC4066B アナログＳＷ

*-----------------------------------------------------------
* TC4066B アナログＳＷ
*------------------------
.subckt tc4066b a1 a2 ctl GND
rpin ctl GND 100Meg
rsin ctl 1 2k
cin 1 GND 30p
.model shsw2 vswitch(RON=2k, ROFF=1G, VON=2 , VOFF=1.75)
sw1 a1 a2 1 GND shsw2
.ends

CMOS inverter

* 0-5V CMOS inverter
*------------------------
.subckt inv in out
rsin in 0 10meg
ep0 out 0 value = { 5 - v(in) }
.ends

パッケージ

package.pdf

..end

Diode

パラメータ定義

1N60 ゲルマニウム 2003/10/05 Hal.T

1N752 Zener

1N754 Zener

1N759 Zener

1N914

1N916

ショットキー TTL内部の保護ダイオード

電源用のショットキー ＳＢＤ

1S2074 HItachi Si EP High speed switch CQ 1988/7

1s2075 HItachi Si EP High speed switch

1s2090 HItachi Si EP UHF TV AFC P-64

1s2267 HItachi Si EP UHF TV AFC P-65

1s2268 HItachi Si EP UHF TV AFC P-65

1ss16 Shotkey Barier

1ss81 High-V Switching

1ss82 High-V Switching

1ss86 Hitachi Si SBD UHF-TV tuner Mixer

1ss88 Hitachi Si SBD CATV balanced Mixer

1ss106 Hitachi Si SBD General Detector & High speed SW

1ss108 Hitachi Si SBD General Detector & High speed SW

1SS110 Hitachi Si EP BAND Switching in UHF/VHF TUNER 1992/09/30 Hal.T

1SS174

1sv99 PIN diode

1SV134

DBF150 電源整流用の単相ブリッジ

DZD2.0-24

ED7TV1

GMA02

hse11 Hitachi GaAs SBD BS-Converter(12GHz) Mixer

HVU316 Hitachi BS tuner VC

FC51 Fujitsu tuninge VC FC51A FC51H

Zener diode RD5-24

z6_8 定電圧ダイオード ＴＲ技術 ９１／６ ｐ５１５

接合容量の正確なツエナーモデル

接合容量の正確なLEDモデル

vali200 200Vバリスタ

18v 1.8V limit diode

l3038a レーザー マクロライブラリ

参考特性 1SS351,1N4004,1S1588,MI407,RN731V,1N60,1SS356

Bipola Transistor

パラメータ定義

bip1 TTL NPNバイポーラトランジスタ

2N2222A

2N2907

2N2907A

2N3904

2N3906

2SA817

2SA952

2SA1015 Low Noise Complementary 2SC1815

2SA1016

Q2SA1048

2SA1049

2SA1145

2SA1179

2SA1298

2SA1313

2SA1606

２SA1683

2SA1731

2SB595

2SB631

2SB688

2SB764

2SB799

2SB800

2SC288

2SC945

2SC980A

2SC1627

2SC1675

2SC1781

2SC1815 Complementary 2SA1015

2SC1907

2SC1959

2SC2003

2SC2240

2SC2362

ショットキー　TTL内部の保護ダイオード

電源用のショットキー　ＳＢＤ

DBF150　電源整流用の単相ブリッジ

Zener diode　RD5-24

z6_8　定電圧ダイオード　ＴＲ技術　９１／６　ｐ５１５

vali200　200Vバリスタ

18v　1.8V limit diode

l3038a　レーザーマクロライブラリ

2SA1015　Low Noise Complementary 2SC1815

単層巻のコイル　 .AC でしか使えない

単層巻のコイル　 .tran で使える

３極菅　6C4