Spice Command

★以下はPSPICE５に付属していたHLPファイルから抜粋したものに新たな説明を加えたものです

デバイスモデル

B device - GaAsFET.

B<name> <d> <g> <s> <model> [<area>]

BIN 100 1 0 GFAST
B13 22 14 23 GNOM 2.0

C device - Capacitor.

C<name> <+node> <-node> [<model>] <value> [IC=<initial>]

CLOAD 15 0 20pF
CFDBK 3 33 CMOD 10pF IC=1.5v
IC　シミュレーション開始時の期待電圧、このまま安定するかどうかは回路しだい

D device - Diode.

D<name> <+node> <-node> <model> [area]

DCLAMP 14 0 DMOD
D13 15 17 SWITCH 1.5

E device - (Voltage) Controlled Voltage Source.

E<name> <+node> <-node> <+control> <-control> <gain>
E<name> <+node> <-node> POLY(<value>) < <+control> <-control> > < <coeff> >
E<name> <+node> <-node> VALUE={<exp>}
E<name> <+node> <-node> TABLE {<exp>} < (inval), (outval) >
E<name> <+node> <-node> LAPLACE {<exp>} {<sexp>}
E<name> <+node> <-node> FREQ {<exp>} < (freq, magdb, phasedeg) >

EBUFF 1 2 10 11 1.0
EAMP 13 0 POLY(1) 26 0 500
ENLIN 100 101 POLY(2) 3 0 4 0 0.0 13.6 0.2 0.005
ESQRT 10 0 VALUE = {SQRT(V(5))}
ETAB 20 5 TABLE {V(2)} (-5v,5v) (0v,0v) (5v,-5v)
E1POLE 10 0 LAPLACE {V(1)} {1 / (1 + s)}
EATTEN 20 0 FREQ {V(100)} (0,0,0 10,-2,-5 20,-6,-10)

F device - Current Controlled Current Source.

F<name> <+node> <-node> <vname> <gain>
F<name> <+node> <-node> POLY(<value>) < <vname> > < <coeff> >

FSENSE 1 2 VSENSE 10.0
FAMP 13 0 POLY(1) VIN 500
FNLIN 100 101 POLY(2) V1 v2 0.0 0.9 0.2 0.005

G device - (Voltage) Controlled Current Source.

G<name> <+node> <-node> <+control> <-control> <gain>
G<name> <+node> <-node> POLY(<value>) < <+control> <-control> > < <coeff> >
G<name> <+node> <-node> VALUE={<exp>}
G<name> <+node> <-node> TABLE {<exp>} = < (inval), (outval) >
G<name> <+node> <-node> LAPLACE {<exp>} + {<sexp>}
G<name> <+node> <-node> FREQ {<exp>} < (freq, magdb, phasedeg) >

GBUFF 1 2 10 11 1.0
GAMP 13 0 POLY(1) 26 0 500
GNLIN 100 101 POLY(2) 3 0 4 0 0.0 13.6 0.2 0.005
GSQRT 10 0 VALUE = {SQRT(V(5))}
GTAB 20 5 TABLE{V(2)} = (-5v,5v) (0v,0v) (5v,-5v)
G1POLE 10 0 LAPLACE {V(1)} {1 / (1 + s)}
GATTEN 20 0 FREQ {V(100)} (0,0,0 10,-2,-5 20,-6,-10)

H device - Current Controlled Voltage Source.

H<name> <+node> <-node> <vname> <gain>
H<name> <+node> <-node> POLY(<value>) < <vname> >* < <coeff> >*
HSENSE 1 2 VSENSE 10.0
HAMP 13 0 POLY(1) VIN 500
HNLIN 100 101 POLY(2) V1 v2 0.0 0.9 0.2 0.005

I device - Current Source.

I<name> <+node> <-node> [[DC] <value>] [AC <mag> [<phase>]] [ <transient> ]

Transient Specifications:

EXP(i1 ipk rdelay rtc fdelay ftc)
PULSE(i1 i2 td trise tfall pw per)
PWL(t1 i1 t2 i2 ... tn fn)
SFFM(ioff iampl fc mod fm)
SIN(ioff iampl freq td df phase)

IBIAS 13 0 2.3mA
IAC 2 3 AC .001
IACPHS 2 3 AC .001 90
IPULSE 1 0 PULSE(-1mA 1mA 2ns 2ns 2ns 50ns 100ns)
I3 26 77 DC .002 AC 1 SIN(.002 .002 1.5MEG)

J device - Junction FET.

J<name> <d> <g> <s> <model> [<area]>

JIN 100 1 0 JFAST
J13 22 14 23 JNOM 2.0

K device - Inductor Coupling.

K<name> L<name> < L<name> > <coupling>
K<name> < L<name> >* <coupling> <model> [<size]>

KTUNED L3OUT L4IN .8
KXFR1 LPRIM LSEC .99
KXFR2 L1 L2 L3 L4 .98 KPOT_3C8

L device - Inductor.

L<name> <+node> <-node> [model] <value> [IC=<initial>]

LLOAD 15 0 20mH
L2 1 2 .2e-6
LCHOKE 3 42 LMOD .03
LSENSE 5 12 2uH IC=2mA

M device - MOSFET.

M<name> <d> <g> <s> <sub> <mdl>
+ [L=<value>] [W=<value>]
+ [AD=<value>] [AS=<value>]
+ [PD=<value>] [PS=<value>]
+ [NRD=<value>] [NRS=<value>]
+ [NRG=<value>] [NRB=<value>]

M1 14 2 13 0 PNOM L=25u W=12u
M13 15 3 0 0 PSTRONG
M2A 0 2 100 100 PWEAK L=33u w=12u AD=288p AS=288p PD=60u PS=60u NRD=14 NRS=24 NRG=10

N device - Digital Input.

N<name> <inode> <lonode> hinode> <model> [SIGNAME=<name>] [IS=<init>]
NRESET 7 15 16 FROM_TTL
N12 18 0 100 FROM_CMOS SIGNAME=VCO_GATE IS=0

O device - Digital Output.

O<name> <iface> <ref> <model> [SIGNAME = <name>]

OVCO 17 0 TO_TTL
O5 22 100 TO_CMOS SIGNAME = VCO_OUT

Q device - Bipolar Transistor.

Q<name> <c> <b> <e> [<subs>] <model> [<area>]

Q1 14 2 13 PNPNOM
Q13 15 3 0 1 NPNSTRONG 1.5
Q7 VC 5 12 [SUB] LATPNP

R device - Resistor.

R<name> <+node> <-node> [<model>] <value>

RLOAD 15 0 2k
R2 1 2 2.4e4

S device - Voltage-Controlled Switch.

S<name> <+node> <-node> <+control> <-control> <model>

S12 13 17 2 0 SMOD
SRESET 5 0 15 3 RELAY

T device - Transmission Line.

T<name> <A+> <A-> <B+> <B-> Z0=<value> [TD=<val> | F=<val>[NL=<val>]]

T1 1 2 3 4 Z0=220 TD=115ns
T2 1 2 3 4 Z0=50 F=5MEG NL=0.5

U device - Digital.

U<name> <type> <parms> <node> [<parm> = <val>]
Types: BUF, INV, AND, NAND, OR,
NOR, XOR, NXOR, BUF3, INV3,
AND3, OR3, NOR3, XOR3, NXOR3,
JKFF, DFF, PULLUP, PULLDN,
STIM.

STIM Syntax:
U<name> STIM (<width>,<radices>)
+<node>* <iomodel>
+ [TIMESTEP=stepsize]
+ < <time>,<value> > |
+ < <time> GOTO <label><n>TIMES> |
+ < <time> GOTO <label><rv><val>> |
+ < <time> INCR BY <val> >
+ < <time> DECR BY <val> >>*
<rv> = UNTIL GT|GE|LT|LE

U7 XOR() INA INB OUTXOR DEFGATE DEFIO
U101 STIM( 1, 1 ) IN1 STMIO
+ TIMESTEP=10ns
+ (LABEL=STARTLOOP)
+ (+10c, 0) (+5ns, 1)
+ (+40c GOTO STARTLOOP 1 TIMES)

V device - Voltage Source.

V<name> <+node> <-node> [[DC] <value>] [AC <mag> [<phase>]] [ <transient> ]

Transient Specifications:
EXP(iv vpk rdelay rtc fdelay ftc)
PULSE(v1 v2 td trise tfall pw per)
PWL(t1 v1 t2 v2 ... tn vn)
SFFM(voff vampl fc mod fm)
SIN(voff vampl freq td df phase)

VBIAS 13 0 2.3mV
VAC 2 3 AC .001
VACPHS 2 3 AC .001 90
VPULSE 1 0 PULSE(-1mV 1mV 2ns 2ns 2ns 50ns 100ns)
V3 26 77 DC .002 AC 1 SIN(.002 .002 1.5MEG)

W device - Current-Controlled Switch.

W<name> <+node> <-node> <vname> <model>

W12 13 17 VC WMOD
WRESET 5 0 VRESET RELAY

X device - Subcircuit Call.

X<name> [<node>]* <sname> [PARAMS: <<par>=<val>*>]

X12 100 101 200 201 DIFFAMP
XBUFF 13 15 UNITAMP

オプション

.AC - AC Analysis.

.AC [LIN][OCT][DEC] <points> <start> <end>

.AC LIN 101 10Hz 200Hz
.AC OCT 10 1KHz 16KHz
.AC DEC 20 1MEG 100MEG

.DC - DC Analysis.

.DC [LIN] <varname> <start> <end> <incr> [<nest>]
.DC [OCT][DEC] <varname> <start> <end> <points> [<nest>]
.DC <varname> LIST <value>* [<nest>]

.DC VIN -.25 .25 .05
.DC LIN I2 5mA -2mA 0.1mA
.DC VCE 0v 10v .5v IB 0mA 1mA 50uA
.DC RES RMOD(R) 0.9 1.1 .001
.DC DEC NPN QFAST(IS) 1e-18 1e-14 5
.DC TEMP LIST 0 20 27 50 80
.DC PARAM RS -1 1 0.1

.DISTRIBUTION - User-Defined Dist.

.DISTRIBUTION <name> <<dev> <prob>>*

.DISTRIBUTION bimodal (-1,1)(-.5,1)(-.5,0)(.5,0)(.5,1)(1,1)

.END - End Circuit.

.END

.ENDS - End Subcircuit.

.ENDS 741

.FOUR - Fourier Analysis.

.FOUR <freq> <output var>*

.FOUR 10KHz v(5) v(6,7)

.FUNC - Function.

.FUNC <name>([arg*]) <body>

.FUNC DR(D) D/57.296
.FUNC E(X) EXP(X)
.FUNC APBX(A,B,X) A+B*X

.IC - Initial Transient Conditions.

.IC < <vnode> = <value> >*

.IC V(2)=3.4 V(102)=0

.INC - Include File.

.INC <name>

.INC SETUP.CIR
.INC C:\\PSLIB\\VCO.CIR

.LIB - Library FIle.

.LIB [<name>]

.LIB
.LIB OPNOM.LIB
.LIB C:\\PSLIB\\QNOM.LIB

.MC - Monte Carlo Analysis.

.MC <#runs> [DC][AC][TRAN] <opvar> <func> <option>*

.MC 10 TRAN V(5) YMAX
.MC 50 DC IC(Q7) MIN LIST
.MC 20 AC VP(13,5) RISE_EDGE(1.0) LIST OUTPUT ALL

.WCASE - Worst Case Analysis.

.WCASE <analysis> <opvar> <func> <option>

.WCASE DC V(4,5) YMAX
.WCASE TRAN V(1) FALL_EDGE(3.5v) VARY BOTH BY RELTOL DEVICES RL

.MODEL - Model.

.MODEL <name> <type> [<param>=<value> [<tol>]]

Typename Devname Devtype
CAP Cxxx capacitor
IND Lxxx inductor
RES Rxxx resistor
D Dxxx diode
NPN Qxxx NPN bipolar
PNP Qxxx PNP bipolar
LPNP Qxxx lateral PNP
NJF Jxxx N-channel JFET
PJF Jxxx P-channel JFET
NMOS Mxxx N-channel MOSFET
PMOS Mxxx P-channel MOSFET
GASFET Bxxx N-channel GaAsFET
CORE Kxxx nonlinear core
VSWITCH Sxxx v/c switch
ISWITCH Wxxx c/c switch
DINPUT Nxxx digital i/p
DOUTPUT Oxxx digital o/p

.MODEL RMAX RES (R=1.5 TC=.02 TC2=.005)
.MODEL QDRIV NPN (IS=1e-7 BF=30)
.MODEL DLOAD D (IS=1e-9 DEV 5% LOT 10%)

.NODESET - Nodeset.

.NODESET < <node>=<value> >

.NODESET V(2)=3.4 V(3)=-1V

.NOISE - Noise Analysis.

.NOISE <opvar> <name> [<ival>]

.NOISE V(5) VIN
.NOISE V(4,5) ISRC 20

.OPTIONS - Options.

.OPTIONS [<fopt>*] [<vopt>=<value>*]

Flag Options
ACCT summary & accounting
EXPAND show subcircuit expansion
LIBRARY list lines from library files
LIST output summary
NODE output netlist
NOECHO suppress listing
NOMOD suppress model param listing
NOPAGE suppress banners
OPTS output option values

Value Options
ABSTOL best accuracy of currents
CHGTOL best accuracy of charges
CPTIME CPU time allowed
DEFAD MOSFET default AD
DEFAS MOSFET default AS
DEFL MOSFET default L
DEFW MOSFET default W
GMIN min conductance, any branch
ITL1 DC & bias pt blind limit
ITL2 DC & bias pt guess limit
ITL4 transient per-point limit
ITL5 transient total, all points
LIMPTS max for print/plot
NUMDGT #digits output
PIVREL rel mag for matrix pivot
PIVTOL abs mag for matrix pivot
RELTOL rel accuracy of V's and I's
TNOM default temp
TRTOL transient accuracy adjustment
VNTOL best accuracy of voltages
WIDTH output width

Examples:
.OPTIONS NOECHO NOMOD RELTOL=.01
.OPTIONS ACCT DEFL=12u DEFW=8u

.PARAM - Global Parameter.

.PARAM < <name>=<value> >

.PARAM pi=3.14159265
.PARAM RSHEET=120, VCC=5V

.PLOT - Plot.

.PLOT [DC][AC][NOISE][TRAN] [ [<opvar>*] [(<lo>,<hi>)] ]*

.PLOT DC V(3) V(2,3) V(R1) I(VIN)
.PLOT AC VM(2) VP(2) VG(2)
.PLOT TRAN V(3) V(2,3) (0,5V) ID(M2) I(VCC) (-50mA,50mA)

.PRINT - Print.

s:
.PRINT [DC][AC][NOISE][TRAN] [<opvar>*]

.PRINT DC V(3) V(2,3) V(R1) IB(Q13)
.PRINT AC VM(2) VP(2) VG(5) II(7)
.PRINT NOISE INOISE ONOISE DB(INOISE)

.PROBE - Probe.

.PROBE[/CSDF]
.PROBE[/CSDF] [<opvar>*]

.PROBE
.PROBE v(2) I(R2) VBE(Q13) VDB(5)
.PROBE/CSDF

.SENS - Sensitivity Analysis.

.SENS <opvar>*

.SENS V(9) V(4,3) I(VCC)

.STEP - Stepped Analysis.

.STEP [LIN] <varname> <start> <end> <incr>
.STEP [OCT][DEC] <varname> <start> <end> <points>
.STEP <varname> LIST <value>*

.STEP VIN -.25 .25 .05
.STEP LIN I2 5mA -2mA 0.1mA
.STEP RES RMOD(R) 0.9 1.1 .001
.STEP TEMP LIST 0 20 27 50 80
.STEP PARAM X 1 5 0.1

.SUBCKT - Subcircuit Definition.

.SUBCKT <name> [<node>*] [PARAMS: <par>[=<val>]* ]

.SUBCKT OPAMP 1 2 101 102
.SUBCKT FILTER IN OUT PARAMS: CENTER, WIDTH=10KHz

.TEMP - Temperature.

.TEMP <value>*

.TEMP 125
.TEMP 0 27 125

.TF - Transfer Function.

.TF <opvar> <ipsrc>

.TF V(5) VIN
.TF I(VDRIV) ICNTRL

.TRAN - Transient Analysis.

.TRAN[/OP] <pstep> <ftime> [<noprint> [<ceiling>]] [UIC]

.TRAN 1nS 100nS
.TRAN/OP 1nS 100nS 20nS UIC
.TRAN 1nS 100nS 0nS .1nS

.WIDTH - Width.

.WIDTH OUT=<val>

.WIDTH OUT=80

Output Variables:

DC Sweep and Transient:
V(<node>)
V(<+node>,<-node>)
V(<name>)
Vx(<name>)
Vxy(<name>)
Vz(<name>)
I(<name>)
Ix(<name>)
Iz(<name>)
Devtypes: C/D/E/F/G/H/I/L/R/V
xy: D/G/S (B)
xy: D/G/S (J)
xy: D/G/S/B (M)
xy: C/B/E/S (Q)
z: A/B
AC Analysis:
Suffices:
M magnitude
DB magnitude
P phase
G group delay
R real
I imaginary
Devtypes: C/I/L/R/T/V
Noise Analysis:
INOISE
ONOISE
DB(INOISE)
DB(ONOISE)

..end